home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / umich / falcon / programm.ing / nt_dsp1.lzh / NT_DSP1.MSA / FNTNS / LOG2NRM.ASM < prev    next >
Assembly Source File  |  1989-01-24  |  2KB  |  63 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Normalizing Base 2 Logarithm Macro
  7. ; 
  8. ; Last Update 30 Mar 87   Version 1.0
  9. ;
  10. log2nrm macro
  11. log2nrm ident   1,0
  12. ;
  13. ;       This program calculates the base 2 logarithm of an unnormalized
  14. ;       24 bit fraction "x" in register A and returns a scaled fraction
  15. ;       "y" in register A.
  16. ;
  17. ;       y = log2(x)/32.0        where   2**(-23) =< x < 1.0
  18. ;                                       -23/32 =< y < 0.0
  19. ;
  20. ;       Note - "x" must be a non-zero, positive fraction.
  21. ;
  22. ;       Three steps are required.
  23. ;
  24. ;       1. Normalize "x" so that 0.5 =< A < 1.0.
  25. ;       2. Calculate the log2(A).
  26. ;       3. Divide the result by 32.0
  27. ;
  28. ;
  29. ;       Step 1 - Normalize A to get value between .5 and 1.0
  30. ;
  31.         move    #-1,m1          ;linear addressing
  32.         move    m1,m7
  33.         move    m7,r7           ;initial count = -1
  34.         rep     #23             ;normalize to between .5 and 1.0
  35.         norm    r7,a            ;shift left and decrement r7 if needed
  36.         move    #pcoef,r1       ;point to polynomial coefficients for log2
  37.         move    a,x0            ;put normalized number in x0
  38. ;
  39. ;       Step 2 - Calculate LOG2 by polynomial approximation.  8 Bit accuracy.
  40. ;
  41. ;       LOG2(x) = 4.0* (-.3372223 x*x + .9981958 x - .6626105)
  42. ;                           a2             a1            a0
  43. ;       where  0.5 <= x < 1.0
  44. ;
  45. ;       r1 initially points to the coefficients in y memory in the
  46. ;       order: a1,a2,a0
  47. ;
  48.         mpyr    x0,x0,a  y:(r1)+,y0     ;x**2, get a1
  49.         mpy     x0,y0,a  a,x1 y:(r1)+,y0        ;a1*x, mv x**2, get a2
  50.         mac     x1,y0,a  y:(r1)+,y0     ;a2* x**2, get a0
  51.         add     y0,a                    ;add in a0
  52.         asl     a                       ;multiply by 4
  53.         asl     a
  54. ;
  55. ;       Step 3 - Divide result by 32.
  56. ;
  57.         asl     a                       ;shift out sign bit
  58.         move    r7,a2                   ;new sign = characteristic
  59.         rep     #6                      ;divide by 32, create sign bit
  60.         asr     a
  61.         rnd     a                       ;round result
  62.         endm
  63.